PA-SCECFG

BUT

Cette instruction permet de déclencher le parcours d’un scénario de configuration technico-commerciale ; dans le cas d’un scénario multi-contexte, le parcours est itératif : chaque itération correspond à un contexte et l’ordre de parcours correspond à l’arborescence récursive des contextes du scénario ; dans le cas d’un scénario mono-contexte, une seule itération est effectuée.

Chaque itération déclenchée par cette instruction permet de se positionner sur un contexte et d’accéder à toute variable du contexte (par la fonction LEC-SCECFG) et de parcourir les informations techniques du contexte (par l’instruction PA-IT-SCECFG).

Cette fonction est disponible uniquement dans les requêtes de type REB.

SYNTAXE

PARCOURS SCENARIO DE CONFUGURATION,

ENTITE = ARTICLE / LIGNE DE COMMANDE

, ARTICLE = Réf.Article,

Ou , NUM.CDE=Num.Cde , LIG.CDE= Lig.Cde,

ERREUR = Erreur

PARAMETRES

Paramètre	E/S	O	Type	Description
ENTITE	E	Oui	Caractère	Indique l’entité à laquelle est rattachée le scénario de configuration parcouru. Les valeurs possibles sont : ARTICLE : correspond à l’entité article standard. LIG.CDE : correspond à l’entité ligne de commande (commerciale ou besoin de gestion).
Réf.Article	E	Oui	Caractère	Référence article standard correspondant au scénario de configuration à parcourir. Peut être donné sous la forme d’une constante ou d’une variable (variable locale ou contextuelle à la requête). A renseigner si entité article standard.
Num.Cde	E	Oui	Caractère	Numéro de commande correspondant au scénario de configuration à parcourir. Peut être donné sous la forme d’une constante ou d’une variable (variable locale ou contextuelle à la requête). A renseigner si entité ligne de commande.
Lig.Cde	E	Oui	Caractère	Numéro de ligne de commande commerciale ou numéro de ligne de besoin de gestion correspondant au scénario de configuration à parcourir. Peut être donné sous la forme d’une constante ou d’une variable (variable locale ou contextuelle à la requête). A renseigner si entité ligne de commande.
Erreur	E	Oui	Caractère	Nom de la variable locale qui va contenir l’erreur éventuelle lors du parcours du scénario de configuration (exemple : il n’existe pas de scénario de configuration).

EXEMPLE

COMMENTAIRE : "Bloc1"

VLO.NumCde = SCR.CdeNumCom

VLO.NumLig = SCR.CdeNumLig

VLO.ListeVar = VCR.cricardeb

VLO.Sep = CLO.","

VLO.Nombre_Var = NB-MOT( SEPARATEUR= VLO.Sep , CHAINE= VLO.ListeVar )

COMMENTAIRE : "Bloc2"

BOUCLE VLO.Indice_Var DE 1 A VLO.Nombre_Var :

VLO.Nom_Var = MOT( SEPARATEUR= VLO.Sep , CHAINE= VLO.ListeVar , NUMERO= VLO.Indice_Var )

VLO.Fct = LEC-SCECFG( ACTION= DEFINITION , TYPE-VARIABLE=VBA , NOM-VARIABLE= VLO.Nom_Var , S:VALEUR= VLO.Retour )

FIN_BLOC

COMMENTAIRE : "Bloc3"

PARCOURS SCENARIO CONFIGURATION ENTITE= LIG.CDE , NUM.CDE= VLO.NumCde , LIG.CDE= VLO.NumLig , ERREUR= VLO.Erreur_Parcours_Nom :

COMMENTAIRE : "Bloc4"

VLO.Fct = LEC-SCECFG( ACTION= CONTEXTE , S:VALEUR= VLO.Rec_Contexte )

VLO.Fct = LEC-SCECFG( ACTION= REC-VALEUR , TYPE-VARIABLE=VBA , NOM-VARIABLE= CLO."di-niveau" , S:VALEUR= VLO.Val_Var )

VLO.Rec_Niveau = ENTIER( VALEUR= VLO.Val_Var )

VLO.Chaine = CLO.""

BOUCLE VLO.Indice_Var DE 1 A VLO.Nombre_Var :

VLO.Nom_Var = MOT( SEPARATEUR= VLO.Sep , CHAINE= VLO.ListeVar , NUMERO= VLO.Indice_Var )

VLO.Fct = LEC-SCECFG( ACTION= REC-VALEUR , TYPE-VARIABLE=VBA , NOM-VARIABLE= VLO.Nom_Var , S:VALEUR= VLO.Val_Var )

VLO.Chaine = VLO.Chaine + " " + CLO.";" + VLO.Nom_Var + CLO."=" + VLO.Val_Var

FIN_BLOC

VLO.Compteur_Lien = VLO.Compteur_Lien + CLO.1

CREATION Liste LST.LstNom :

PRENDRE LstNom NumOrd = VLO.Compteur_Lien

PRENDRE LstNom Niveau = VLO.Rec_Niveau

PRENDRE LstNom Ident = VLO.Rec_Contexte

PRENDRE LstNom Chaine = VLO.Chaine

FIN_BLOC

COMMENTAIRE : "Bloc5"

PARCOURS INF.TEC. SCENARIO CONFIGURATION , ERREUR= VLO.Erreur_Parcours_ITs :

COMMENTAIRE : "Bloc6"

VLO.Fct = LEC-SCECFG( ACTION= REC-VALEUR , TYPE-VARIABLE=VBA , NOM-VARIABLE= CLO."di-t-type" , S:VALEUR= VLO.Rec_IT_Type )

TRACE= CLO."Retour Lecture IT" + " " + VLO.Rec_IT_Type + " " + CLO."Valeur Type IT=" + " " + VLO.Rec_IT_Type

VLO.Fct = LEC-SCECFG( ACTION= REC-VALEUR , TYPE-VARIABLE=VBA , NOM-VARIABLE= CLO."di-t-sstype" , S:VALEUR= VLO.Rec_IT_SsType )

VLO.Fct = LEC-SCECFG( ACTION= REC-VALEUR , TYPE-VARIABLE=VBA , NOM-VARIABLE= CLO."di-t-code" , S:VALEUR= VLO.Rec_IT_Code )

VLO.Fct = LEC-SCECFG( ACTION= REC-VALEUR , TYPE-VARIABLE=VBA , NOM-VARIABLE= CLO."di-t-valeur" , S:VALEUR= VLO.Rec_IT_Valeur )

VLO.Compteur_Lien = VLO.Compteur_Lien + CLO.1

CREATION Liste LstNom :

PRENDRE LstNom NumOrd = VLO.Compteur_Lien

PRENDRE LstNom Ident = VLO.Rec_Contexte

PRENDRE LstNom Type = VLO.Rec_IT_Type

PRENDRE LstNom SsType = VLO.Rec_IT_SsType

PRENDRE LstNom Code = VLO.Rec_IT_Code

PRENDRE LstNom Valeur = VLO.Rec_IT_Valeur

FIN_BLOC

COMMENTAIRE : "Bloc7"

SI VLO.Erreur_Parcours_ITs <> CLO.""

TRACE= CLO."Code erreur parcours nomenclature" + " " + VLO.Erreur_Parcours_ITs

CREATION Liste LstNom :

PRENDRE LstNom Ident = VLO.Rec_Pointeur

PRENDRE LstNom Chaine = CLO."Erreur ITs" + " " + VLO.Erreur_Parcours_ITs

FIN_BLOC

COMMENTAIRE : "Bloc8"

SI VLO.Erreur_Parcours_Nom <> CLO.""

TRACE= CLO."Code erreur parcours nomenclature" + " " + VLO.Erreur_Parcours_Nom

CREATION Liste LstNom :

PRENDRE LstNom Chaine = CLO."Erreur parcours =" + " " + VLO.Erreur_Parcours_Nom

FIN_BLOC

Dans cet exemple, les points particuliers identifiés par les commentaires sont les suivants :

Bloc 1 : les instructions qui suivent permettent de définir les variables contextuelles de la requête à partir des critères.
Bloc 2 : les instructions qui suivent utilisent la fonction LEC-SCECFG avec l’action DEFINITION pour déclarer les variables devant être utilisées.
Bloc 3 : l’instruction qui suit déclenche le parcours itératif de la nomenclature de contexte d’un scénario de configuration sur une ligne de commande.
Bloc 4 : les instructions qui suivent utilisent la fonction LEC-SCECFG pour récupérer des valeurs de variables VBAs du scénario de configuration, les mémoriser dans des variables pour les enregistrer par la suite dans une liste.
Bloc 5 : l’instruction qui suit déclenche le parcours itératif des informations techniques du contexte du scénario de con figuration en cours de parcours.
Bloc 6 : les instructions qui suivent utilisent la fonction LEC-SCECFG pour récupérer des valeurs des informations techniques du contexte courant, les mémoriser dans des variables pour les enregistrer par la suite dans une liste.
Bloc 7 : les instructions qui suivent permettent de piloter l’erreur éventuelle sur le parcours des informations techniques.
Bloc 8 : les instructions qui suivent permettent de piloter l’erreur éventuelle sur le parcours des nomenclatures de contextes.

NOTES

La variable locale correspondant à l’erreur va contenir un code erreur si le parcours ne peut être exécuté (cas ou l’article ou la ligne de commande ou de besoin de gestion donnés sont incohérents) ou bien si le scénario de configuration n’est pas définie pour l’entité donnée. Les valeurs possibles sont :
*ERR:CTX-NON-POS : contexte non positionné
*ERR:PAR-NOM-ENC : parcours déjà en cours
*ERR:DEF-VAR-NDE : définition variables vide
*ERR:LIG-PAS-CFG : pas de cfg pour lig.cde
*ERR:LIG-PAS-CFG : pas cfg pour lig.cde/ges
*ERR:LCG-CDE-INC : lig.cde/ges inconnue
*ERR:ART-PAS-CFG : pas cfg pour article
*ERR:ART-INC : article inconnu
*ERR:ENT-INC : entité inconnue
*ERR:CTX-NON-POS : contexte non positionné
Cette instruction permet de parcourir un scénario de configuration : s’il est composé d’une nomenclature de contextes, la parcours est effectué sous forme itérative : le premier contexte correspond à celui du niveau 0, puis le parcours est effectué dans l’ordre récursif de la nomenclature de contexte ; si le scénario de configuration est composé d’un seul contexte ou est mono-contexte, cette instruction permet d’accéder au contexte en question.
Cette instruction permet d’utiliser la fonction LEC-SCEDEF pour accéder à toute variable contextuelle du contexte de l’itération.
Cette instruction permet d’utiliser l’instruction PA-IT-SCEDEF pour parcourir les informations techniques du contexte de l’itération courante.